import QtQuick
import QtQuick.Controls

import "../style"

Menu {
    id: root

    property var analysisController: null
    property string markerType: ""
    property int markerIndex: -1

    width: 300
    topPadding: 5
    bottomPadding: 5
    leftPadding: 5
    rightPadding: 5

    background: Rectangle {
        color: "#FFFFFF"
        border.color: "#788797"
        radius: 6
    }

    function markerModel() {
        if (!analysisController)
            return null
        return markerType === "band"
                ? analysisController.bandModel
                : analysisController.harmonicModel
    }

    function marker() {
        var model = markerModel()
        if (!model || markerIndex < 0 || markerIndex >= model.count)
            return null
        return model.get(markerIndex)
    }

    function setMarkerProperty(name, value) {
        var model = markerModel()
        if (!model || markerIndex < 0 || markerIndex >= model.count)
            return
        model.setProperty(markerIndex, name, value)
        analysisController.saveCurrentMarkers()
        analysisController.markersUpdated()
    }

    AppMenuItem {
        text: root.markerType === "band"
              ? "Полосовой маркер" : "Гармонический маркер"
        enabled: false
        font.bold: true
    }

    AppMenuItem {
        text: {
            var value = root.marker()
            if (!value)
                return "Параметры недоступны"
            if (root.markerType === "band") {
                return "Диапазон: "
                        + Number(value.leftFrequency).toFixed(3)
                        + " — "
                        + Number(value.rightFrequency).toFixed(3)
            }
            return "Частота: "
                    + Number(value.frequency).toFixed(3)
                    + "; гармоник: " + value.harmonicCount
        }
        enabled: false
    }

    AppMenuSeparator {}

    AppMenuItem {
        text: "Показывать на графике"
        checkable: true
        checked: {
            var value = root.marker()
            return value ? value.markerVisible : false
        }
        onTriggered: root.setMarkerProperty("markerVisible", checked)
    }

    AppMenuItem {
        text: "Показывать подпись"
        checkable: true
        checked: {
            var value = root.marker()
            return value ? value.labelVisible : false
        }
        onTriggered: root.setMarkerProperty("labelVisible", checked)
    }

    AppMenuItem {
        visible: root.markerType === "harmonic"
        text: "Привязка к максимуму"
        checkable: true
        checked: {
            var value = root.marker()
            return value ? value.snapToMaximum : false
        }
        onTriggered: {
            root.setMarkerProperty("snapToMaximum", checked)
            var value = root.marker()
            if (checked && value)
                root.analysisController.updateHarmonicFrequency(
                            root.markerIndex, value.frequency)
        }
    }

    AppMenuSeparator {}

    AppMenuItem {
        text: "Удалить"
        onTriggered: {
            if (!root.analysisController)
                return
            if (root.markerType === "band")
                root.analysisController.removeBand(root.markerIndex)
            else
                root.analysisController.removeHarmonic(root.markerIndex)
        }
    }
}
