import QtQuick
import QtQuick.Controls
import QtQuick.Layouts

import "../style"

AbstractButton {
    id: control

    property string densityMode: "normal"

    ApplicationStyle {
        id: applicationStyle
        densityMode: control.densityMode
    }

    Layout.preferredWidth: 20
    Layout.preferredHeight: 20
    implicitWidth: 20
    implicitHeight: applicationStyle.smallControlHeight
    padding: 0
    checkable: true
    focusPolicy: Qt.NoFocus
    hoverEnabled: enabled

    contentItem: Item {
        visible: control.checked

        Rectangle {
            x: 4
            y: 9.5
            width: 6
            height: 2.2
            radius: 1.1
            rotation: 45
            transformOrigin: Item.Left
            color: applicationStyle.inverseTextColor
        }

        Rectangle {
            x: 7.5
            y: 13
            width: 11.5
            height: 2.2
            radius: 1.1
            rotation: -47
            transformOrigin: Item.Left
            color: applicationStyle.inverseTextColor
        }
    }

    background: Rectangle {
        radius: 2
        color: !control.enabled
               ? (control.checked
                  ? applicationStyle.controlBorderColor
                  : applicationStyle.disabledControlColor)
               : control.checked
                 ? (control.down
                    ? applicationStyle.accentPressedColor
                    : control.hovered
                      ? applicationStyle.accentHoverColor
                      : applicationStyle.accentColor)
                 : control.down
                   ? applicationStyle.controlPressedColor
                   : control.hovered
                     ? applicationStyle.controlColor
                     : applicationStyle.panelColor
        border.width: 1
        border.color: control.checked
                      ? (control.enabled
                         ? applicationStyle.accentColor
                         : applicationStyle.controlBorderColor)
                      : applicationStyle.controlBorderColor

    }
}
