import QtQuick

SpectrumChart {
    readonly property var signalMarkerController: analysisController
                                                    ? analysisController.signalBandControllerObject
                                                    : null
    markerController: signalMarkerController
    bandModel: signalMarkerController ? signalMarkerController.bandModel : null
    readonly property var previewMetadata: analysisController
                                           ? analysisController.signalMetadata
                                           : null
    readonly property real previewDuration: {
        var metadata = previewMetadata
        if (!metadata)
            return NaN
        var duration = Number(metadata.duration)
        if (isFinite(duration) && duration > 0)
            return duration
        var sampleRate = Number(metadata.sampleRate)
        var totalSamples = Number(metadata.totalSamples)
        return isFinite(sampleRate) && sampleRate > 0
                && isFinite(totalSamples) && totalSamples > 0
                ? totalSamples / sampleRate : NaN
    }
    dataResolutionX: {
        var metadata = previewMetadata
        var sampleRate = Number(metadata ? metadata.sampleRate : NaN)
        return isFinite(sampleRate) && sampleRate > 0
                ? 1 / sampleRate : NaN
    }

    title: "Временной сигнал"
    xAxisTitle: "Время"
    yAxisTitle: "Амплитуда"
    cursorEnabled: true
    cursorXUnit: "с"
    cachedNavigationEnabled: true
    spectrumRangeReloadEnabled: false
    spectrumLegendEnabled: false
    comparisonSpectraEnabled: false
    markersEnabled: true
    harmonicMarkersEnabled: false
    showCursorRms: true
    showExceedanceIndicators: false
    cursorXLabel: "Время"
    cursorYLabel: "Значение"
    preserveViewportOnPointsChanged: true
    configuredDataMinimumX: isFinite(previewDuration) ? 0 : NaN
    configuredDataMaximumX: previewDuration

    onNavigationCommitted: function(minimumTime, maximumTime) {
        if (analysisController
                && typeof analysisController.requestSignalRange
                   === "function") {
            lastNavigationRangeRequestIssued = analysisController.requestSignalRange(
                        minimumTime, maximumTime,
                        renderPointBudget())
        }
    }
}
