import QtQml

import "../utils/IdUtils.js" as IdUtils

ListModel {
    id: model

    dynamicRoles: true

    function renumber() {
        for (var index = 0; index < count; ++index) {
            var entry = get(index)
            var previousId = entry.itemId === undefined
                    ? index + 1 : Number(entry.itemId)
            var previousDefaultName = "B" + previousId
            var currentName = entry.markerName === undefined
                    || entry.markerName === null
                    ? "" : String(entry.markerName).trim()
            var customized = entry.markerNameCustomized === undefined
                    ? currentName.length > 0
                      && currentName !== previousDefaultName
                    : Boolean(entry.markerNameCustomized)
            var itemId = index + 1
            setProperty(index, "markerUuid",
                        IdUtils.ensureUuid(entry.markerUuid, "band"))
            setProperty(index, "itemId", itemId)
            setProperty(index, "markerNameCustomized", customized)
            if (!customized)
                setProperty(index, "markerName", "B" + itemId)
        }
    }

    function setMarkerName(index, markerName) {
        if (index < 0 || index >= count)
            return false
        var defaultName = "B" + (index + 1)
        var value = String(markerName || "").trim()
        var customized = value.length > 0 && value !== defaultName
        setProperty(index, "markerNameCustomized", customized)
        setProperty(index, "markerName",
                    customized ? value : defaultName)
        return true
    }

    function indexByUuid(markerUuid) {
        var requested = String(markerUuid || "")
        if (requested.length === 0)
            return -1
        for (var index = 0; index < count; ++index) {
            if (String(get(index).markerUuid || "") === requested)
                return index
        }
        return -1
    }

    function removeByUuid(markerUuid) {
        return removeAt(indexByUuid(markerUuid))
    }

    function add(leftFrequency, rightFrequency, colorValue, rmsValue) {
        renumber()
        var itemId = count + 1
        var left = Math.min(Number(leftFrequency),
                            Number(rightFrequency))
        var right = Math.max(Number(leftFrequency),
                             Number(rightFrequency))
        append({
            markerUuid: IdUtils.createUuid("band"),
            itemId: itemId,
            markerName: "B" + itemId,
            markerNameCustomized: false,
            leftFrequency: left,
            rightFrequency: right,
            rmsValue: Number(rmsValue),
            colorValue: colorValue || "#005FCC",
            labelVisible: true,
            markerVisible: true
        })
        return count - 1
    }

    function updateRange(index, leftFrequency, rightFrequency,
                         rmsValue) {
        if (index < 0 || index >= count)
            return false
        setProperty(index, "leftFrequency",
                    Math.min(Number(leftFrequency),
                             Number(rightFrequency)))
        setProperty(index, "rightFrequency",
                    Math.max(Number(leftFrequency),
                             Number(rightFrequency)))
        setProperty(index, "rmsValue", Number(rmsValue))
        return true
    }

    function removeAt(index) {
        if (index < 0 || index >= count)
            return false
        remove(index)
        renumber()
        return true
    }
}
