import QtQml

import "../utils/IdUtils.js" as IdUtils

ListModel {
    id: model

    dynamicRoles: true

    function renumber() {
        for (var index = 0; index < count; ++index) {
            var entry = get(index)
            var previousId = entry.itemId === undefined
                    ? index + 1 : Number(entry.itemId)
            var previousDefaultName = "H" + previousId
            var currentName = entry.markerName === undefined
                    || entry.markerName === null
                    ? "" : String(entry.markerName).trim()
            var customized = entry.markerNameCustomized === undefined
                    ? currentName.length > 0
                      && currentName !== previousDefaultName
                    : Boolean(entry.markerNameCustomized)
            var itemId = index + 1
            setProperty(index, "markerUuid",
                        IdUtils.ensureUuid(entry.markerUuid,
                                           "harmonic"))
            setProperty(index, "itemId", itemId)
            setProperty(index, "markerNameCustomized", customized)
            if (!customized)
                setProperty(index, "markerName", "H" + itemId)
        }
    }

    function setMarkerName(index, markerName) {
        if (index < 0 || index >= count)
            return false
        var defaultName = "H" + (index + 1)
        var value = String(markerName || "").trim()
        var customized = value.length > 0 && value !== defaultName
        setProperty(index, "markerNameCustomized", customized)
        setProperty(index, "markerName",
                    customized ? value : defaultName)
        return true
    }

    function indexByUuid(markerUuid) {
        var requested = String(markerUuid || "")
        if (requested.length === 0)
            return -1
        for (var index = 0; index < count; ++index) {
            if (String(get(index).markerUuid || "") === requested)
                return index
        }
        return -1
    }

    function removeByUuid(markerUuid) {
        return removeAt(indexByUuid(markerUuid))
    }

    function add(frequency, colorValue, snapToMaximum) {
        renumber()
        var itemId = count + 1
        append({
            markerUuid: IdUtils.createUuid("harmonic"),
            itemId: itemId,
            markerName: "H" + itemId,
            markerNameCustomized: false,
            frequency: Number(frequency),
            harmonicCount: 1,
            lineWidth: 1,
            colorValue: colorValue || "#6F42C1",
            snapToMaximum: snapToMaximum === undefined
                         ? true : Boolean(snapToMaximum),
            labelVisible: true,
            markerVisible: true
        })
        return count - 1
    }

    function updateFrequency(index, frequency) {
        if (index < 0 || index >= count)
            return false
        setProperty(index, "frequency", Number(frequency))
        return true
    }

    function removeAt(index) {
        if (index < 0 || index >= count)
            return false
        remove(index)
        renumber()
        return true
    }
}
