import QtQuick
import QtQuick.Controls

AbstractButton {
    id: control

    property string densityMode: "normal"
    property int hoverAnimationDuration: applicationStyle.hoverAnimationDuration
    property bool accentButton: false
    property color accentColor: applicationStyle.accentColor

    ApplicationStyle {
        id: applicationStyle
        densityMode: control.densityMode
    }

    hoverEnabled: enabled
    opacity: 1
    implicitHeight: applicationStyle.controlHeight
    leftPadding: applicationStyle.buttonHorizontalPadding
    rightPadding: applicationStyle.buttonHorizontalPadding
    topPadding: applicationStyle.controlVerticalPadding
    bottomPadding: applicationStyle.controlVerticalPadding
    font.pixelSize: applicationStyle.fontSizeControl

    contentItem: Text {
        renderType: Text.NativeRendering
        text: control.text
        color: control.accentButton
               ? applicationStyle.inverseTextColor
               : !control.enabled
               ? applicationStyle.stronglyDisabledTextColor
               : control.checked
                 ? applicationStyle.inverseTextColor
                 : applicationStyle.controlTextColor
        font: control.font
        horizontalAlignment: Text.AlignHCenter
        verticalAlignment: Text.AlignVCenter
        elide: Text.ElideRight
    }

    background: Rectangle {
        radius: applicationStyle.controlRadius
        color: control.accentButton
               ? control.accentColor
               : !control.enabled
               ? applicationStyle.disabledControlColor
               : control.checked
                 ? (control.down
                    ? applicationStyle.accentPressedColor
                    : control.hovered
                      ? applicationStyle.accentHoverColor
                      : applicationStyle.accentColor)
               : control.down
                 ? applicationStyle.controlPressedColor
                 : control.hovered
                   ? applicationStyle.controlHoverColor
                   : applicationStyle.controlColor
        border.width: control.activeFocus
                      ? applicationStyle.focusBorderWidth
                      : applicationStyle.borderWidth
        border.color: control.accentButton
                      ? Qt.darker(control.accentColor, 1.12)
                      : !control.enabled
                        ? applicationStyle.disabledBorderColor
                      : control.activeFocus || control.checked
                        ? applicationStyle.focusColor
                        : applicationStyle.controlBorderColor

        Rectangle {
            anchors.fill: parent
            radius: parent.radius
            visible: control.accentButton
            color: applicationStyle.pressedOverlayColor
            opacity: control.down
                     ? 0.16
                     : control.hovered ? 0.08 : 0

            Behavior on opacity {
                NumberAnimation {
                    duration: control.hoverAnimationDuration
                    easing.type: Easing.OutCubic
                }
            }
        }
    }
}
