import QtQuick
import QtQuick.Controls.Basic

ToolButton {
    id: control

    property string densityMode: "normal"
    property int hoverAnimationDuration: applicationStyle.hoverAnimationDuration

    ApplicationStyle {
        id: applicationStyle
        densityMode: control.densityMode
    }

    hoverEnabled: enabled
    implicitWidth: applicationStyle.toolButtonSize
    implicitHeight: applicationStyle.toolButtonSize
    padding: 5
    font.pixelSize: applicationStyle.fontSizeControl

    contentItem: Text {
        renderType: Text.NativeRendering
        text: control.text
        color: !control.enabled
               ? applicationStyle.stronglyDisabledTextColor
               : control.checked
                 ? applicationStyle.inverseTextColor
                 : applicationStyle.controlTextColor
        font: control.font
        horizontalAlignment: Text.AlignHCenter
        verticalAlignment: Text.AlignVCenter
        elide: Text.ElideRight
    }

    background: Rectangle {
        radius: applicationStyle.controlRadius
        color: !control.enabled
               ? applicationStyle.disabledControlColor
               : control.checked
                 ? (control.down
                    ? applicationStyle.accentPressedColor
                    : control.hovered
                      ? applicationStyle.accentHoverColor
                      : applicationStyle.accentColor)
               : control.down
                 ? applicationStyle.controlPressedColor
                 : control.hovered
                   ? applicationStyle.controlHoverColor
                   : applicationStyle.controlColor
        border.width: control.activeFocus
                      ? applicationStyle.focusBorderWidth
                      : applicationStyle.borderWidth
        border.color: !control.enabled
                      ? applicationStyle.disabledBorderColor
                      : control.activeFocus || control.checked
                        ? applicationStyle.focusColor
                        : applicationStyle.controlBorderColor

    }
}
