import QtQuick
import QtQuick.Window

MouseArea {
    id: root

    property bool dragToDetachEnabled: false
    property var moveWindow: null
    property real dragThreshold: 8

    signal detachRequested(real globalX, real globalY,
                           real pressOffsetX, real pressOffsetY)
    signal windowMoveStarted(real globalX, real globalY)
    signal windowMoveUpdated(real globalX, real globalY)
    signal windowMoveFinished(real globalX, real globalY)

    acceptedButtons: Qt.LeftButton
    hoverEnabled: true
    cursorShape: dragToDetachEnabled || moveWindow
                 ? Qt.SizeAllCursor : Qt.ArrowCursor

    property point pressGlobalPosition: Qt.point(0, 0)
    property point pressLocalPosition: Qt.point(0, 0)
    property bool detachStarted: false
    property bool windowMoveActive: false

    onPressed: function(mouse) {
        pressLocalPosition = Qt.point(mouse.x, mouse.y)
        pressGlobalPosition = root.mapToGlobal(
                    Qt.point(mouse.x, mouse.y))
        detachStarted = false
        windowMoveActive = false
    }

    onPositionChanged: function(mouse) {
        if (!pressed)
            return

        var globalPosition = root.mapToGlobal(
                    Qt.point(mouse.x, mouse.y))
        if (moveWindow) {
            var moveDeltaX = globalPosition.x
                    - pressGlobalPosition.x
            var moveDeltaY = globalPosition.y
                    - pressGlobalPosition.y
            if (!windowMoveActive
                    && Math.abs(moveDeltaX) + Math.abs(moveDeltaY)
                    >= dragThreshold) {
                windowMoveActive = true
                root.windowMoveStarted(globalPosition.x,
                                       globalPosition.y)
                if (moveWindow.startSystemMove)
                    moveWindow.startSystemMove()
            }
            if (!windowMoveActive)
                return
            root.windowMoveUpdated(globalPosition.x,
                                   globalPosition.y)
            return
        }

        if (!dragToDetachEnabled || detachStarted)
            return

        var deltaX = globalPosition.x - pressGlobalPosition.x
        var deltaY = globalPosition.y - pressGlobalPosition.y
        if (Math.abs(deltaX) + Math.abs(deltaY) < dragThreshold)
            return

        detachStarted = true
        root.detachRequested(globalPosition.x,
                             globalPosition.y,
                             pressLocalPosition.x,
                             pressLocalPosition.y)
    }

    onReleased: function(mouse) {
        if (!moveWindow || !windowMoveActive)
            return
        var globalPosition = root.mapToGlobal(
                    Qt.point(mouse.x, mouse.y))
        root.windowMoveFinished(globalPosition.x,
                                globalPosition.y)
        windowMoveActive = false
    }

    onCanceled: {
        if (!moveWindow || !windowMoveActive)
            return
        var globalPosition = root.mapToGlobal(
                    Qt.point(mouseX, mouseY))
        root.windowMoveFinished(globalPosition.x,
                                globalPosition.y)
        windowMoveActive = false
    }

    onDoubleClicked: function(mouse) {
        if (!moveWindow)
            return
        if (moveWindow.visibility === Window.Maximized)
            moveWindow.showNormal()
        else
            moveWindow.showMaximized()
    }
}
