import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import QtQuick.Window

import "../views"
import "../style"

Window {
    id: root

    property var recordsController: null

    signal dockRequested()
    signal windowDragUpdated(real globalX, real globalY)
    signal windowDragFinished(real globalX, real globalY)

    width: 820
    height: 210
    minimumWidth: 560
    minimumHeight: 180
    visible: false
    flags: Qt.Window | Qt.FramelessWindowHint
    color: "#E7ECF2"
    title: "Период и результаты — VibroExplorer"

    function openPanel() {
        show()
        raise()
        requestActivate()
    }

    onClosing: function(close) {
        root.dockRequested()
    }

    ColumnLayout {
        anchors.fill: parent
        anchors.margins: 8
        spacing: 6

        PanelTitleBar {
            Layout.fillWidth: true
            title: "Период и результаты"
            moveWindow: root
            closeButtonVisible: true
            onCloseRequested: root.close()
            onWindowMoveStarted: function(globalX, globalY) {
                moveTracker.begin(globalX, globalY)
            }
            onWindowMoveUpdated: function(globalX, globalY) {
                moveTracker.pointerMoved(globalX, globalY)
            }
            onWindowMoveFinished: function(globalX, globalY) {
                moveTracker.finish(globalX, globalY)
            }
        }

        RoutePeriodToolbarView {
            Layout.fillWidth: true
            Layout.fillHeight: true
            recordsController: root.recordsController
        }
    }

    Rectangle {
        anchors.fill: parent
        color: "transparent"
        border.width: 1
        border.color: "#788797"
        z: 900
    }

    WindowResizeHandles {
        anchors.fill: parent
        targetWindow: root
        z: 1000
    }

    DockWindowMoveTracker {
        id: moveTracker
        targetWindow: root
        onDragUpdated: function(globalX, globalY) {
            root.windowDragUpdated(globalX, globalY)
        }
        onDragFinished: function(globalX, globalY) {
            root.windowDragFinished(globalX, globalY)
        }
    }
}
