import QtQuick
import QtQuick.Layouts

import "../charts"

DockablePanelWindow {
    id: root

    property var analysisController: null
    property var bandModel: null
    property var harmonicModel: null

    signal comparisonSpectrumDetachRequested(int index)

    width: 1180
    height: 700
    minimumWidth: 360
    minimumHeight: 220
    panelTitle: "Спектр"
    panelCounterText: root.analysisController
                      ? root.analysisController.statusMessage
                      : "Запись не выбрана"
    title: {
        var record = analysisController
                ? analysisController.selectedRecord : null
        return record
                ? "Спектр — " + record.recordFileName
                : "Спектр"
    }

    function openSpectrum() {
        openPanel()
    }

    function openSpectrumForDrag(globalX, globalY,
                                 pressOffsetX, pressOffsetY) {
        openPanelForDrag(globalX, globalY,
                         pressOffsetX, pressOffsetY)
    }

    SpectrumChart {
        Layout.fillWidth: true
        Layout.fillHeight: true
        Layout.minimumWidth: 0
        Layout.minimumHeight: 0
        points: root.visible && root.analysisController
                ? root.analysisController.spectrumPoints : []
        bandModel: root.bandModel
        harmonicModel: root.harmonicModel
        analysisController: root.visible
                            ? root.analysisController : null
        locked: root.locked
        lockButtonVisible: root.systemWindowMode
        onLockToggled: function(locked) { root.lockToggled(locked) }
        onComparisonSpectrumDetachRequested: function(index) {
            root.comparisonSpectrumDetachRequested(index)
        }
        cursorMetricsProvider: function(frequency) {
            return root.analysisController
                    ? root.analysisController
                      .spectrumCursorMetrics(frequency)
                    : null
        }
    }
}
